.text
tmain:			subu	$sp, $sp, 16
			sw	$fp, 4($sp)
			addu	$fp, $sp, 16
			sw	$ra, -8($fp)

			sw	$a0, 0($fp)
			li	$t0, 0
			b	tmain_test
			.data
tmain_msg0:		.asciiz	"Thread "
tmain_msg1:		.asciiz ": "
tmain_msg2:		.asciiz "\n"
			.text
tmain_bod:		la	$a0, tmain_msg0
			li	$v0, 4
			syscall
			lw	$a0, 0($fp)
			li	$v0, 1
			syscall
			la	$a0, tmain_msg1
			li	$v0, 4
			syscall
			move	$a0, $t0
			li	$v0, 1
			syscall
			la	$a0, tmain_msg2
			li	$v0, 4
			syscall
			sw	$t0, -4($fp)
			jal	thr_yield
			lw	$t0, -4($fp)
			addiu	$t0, $t0, 1
			sw	$t0, -4($fp)
tmain_test:		blt	$t0, 10, tmain_bod

			lw	$ra, -8($fp)
			lw	$fp, -12($fp)
			addu	$sp, $sp, 16
			jr	$ra

foo:			subu	$sp, $sp, 12
			sw	$fp, 4($sp)
			addu	$fp, $sp, 12
			sw	$ra, -4($fp)

			.data
foo_msg0:		.asciiz	"I am thread "
foo_msg1:		.asciiz	", and this is "
foo_msg2:		.asciiz	" times through\n"
			.text

			sw	$a0, 0($fp)
			la	$a0, foo_msg0
			li	$v0, 4
			syscall
			lw	$a0, 0($fp)
			li	$v0, 1
			syscall
			la	$a0, foo_msg1
			li	$v0, 4
			syscall
			move	$a0, $a1
			li	$v0, 1
			syscall
			la	$a0, foo_msg2
			li	$v0, 4
			syscall

			jal	thr_yield

			lw	$ra, -4($fp)
			lw	$fp, -8($fp)
			addu	$sp, $sp, 12
			jr	$ra

t2main:			subu	$sp, $sp, 16
			sw	$fp, 4($sp)
			addu	$fp, $sp, 16
			sw	$ra, -8($fp)

			sw	$a0, 0($fp)	# thread_id
			move	$t0, $zero	# i
			b	t2test
t2bod:			sw	$t0, -4($fp)
			move	$a1, $t0
			lw	$a0, 0($fp)
			jal	foo
			.data
t2_msg0:		.asciiz	"[ "
t2_msg1:		.asciiz ":"
t2_msg2:		.asciiz " ]\n"
			.text
			la	$a0, t2_msg0
			li	$v0, 4
			syscall
			lw	$a0, 0($fp)
			li	$v0, 1
			syscall
			la	$a0, t2_msg1
			li	$v0, 4
			syscall
			lw	$t0, -4($fp)
			move	$a0, $t0
			li	$v0, 1
			syscall
			la	$a0, t2_msg2
			li	$v0, 4
			syscall
			jal	thr_yield
			lw	$t0, -4($fp)
			addiu	$t0, $t0, 1
t2test:			blt	$t0, 10, t2bod

			lw	$ra, -8($fp)
			lw	$fp, -12($fp)
			addu	$sp, $sp, 16
			jr	$ra

			.globl main
#
#   8 + 3 * THR_STATE_SIZE + 3 * 4 * 512
# = 8 + 3 * 60 + 3 * 2048
# = 8 + 180 + 6144
# = 6332
#
# fp ->	t2stk	-2044($fp)
#	t1stk	-4092($fp)
#	t0stk	-6140($fp)
#	t2	-6200($fp)
#	t1	-6260($fp)
#	t0	-6320($fp)
#	old-ra	-6324($fp)
#	old-fp	-6328($fp)
# sp ->
main:			subu	$sp, $sp, 6332
			sw	$fp, 4($sp)
			sw	$ra, 8($sp)
			addu	$fp, $sp, 6332

			li	$t0, 2048
			subu	$sp, $sp, 4
			sw	$t0, 4($sp)	# push shared 4th arg

			la	$a3, -6140($fp)
			li	$a2, 0
			la	$a1, tmain
			la	$a0, -6320($fp)
			jal	thr_init

			la	$a3, -4092($fp)
			li	$a2, 1
			la	$a1, tmain
			la	$a0, -6260($fp)
			jal	thr_init

			la	$a3, -2044($fp)
			li	$a2, 2
			la	$a1, t2main
			la	$a0, -6200($fp)
			jal	thr_init

			addu	$sp, $sp, 4	# pop shared 4th arg

			jal	thr_go

			.data
done_msg:		.asciiz "All done!\n"
			.text

			la	$a0, done_msg
			li	$v0, 4
			syscall

			lw	$ra, -6324($fp)
			lw	$fp, -6328($fp)
			addu	$sp, $sp, 6332
			jr	$ra