#
# Tests thr_init after thr_go.
#

#
# fp->	orig a0
#	loop index ($t0)
#	old ra
#	old fp
# sp->
DRVR_THR_STK_SZ=2048
			.data
			.align 2
			#
			# statically allocated space for 5 threads; note
			# that this implies that tmain can be used only
			# once!
			#
bsy_tmain_spawn_stk:	.space DRVR_THR_STK_SZ
			.space DRVR_THR_STK_SZ
			.space DRVR_THR_STK_SZ
			.space DRVR_THR_STK_SZ
			.space DRVR_THR_STK_SZ
bsy_tmain_thr_states:	.space THR_STATE_SIZE
			.space THR_STATE_SIZE
			.space THR_STATE_SIZE
			.space THR_STATE_SIZE
			.space THR_STATE_SIZE
			.text
bsy_tmain:		subu	$sp, $sp, 16
			sw	$fp, 4($sp)
			addu	$fp, $sp, 16
			sw	$ra, -8($fp)

			sw	$a0, 0($fp)

			li	$t0, 0
			b	bsy_tmain_spawn_test
bsy_tmain_spawn:	subu	$sp, $sp, 4
			li	$t1, DRVR_THR_STK_SZ
			sw	$t1, 4($sp)
			li	$a3, 2048
			mul	$a3, $a3, $t0
			la	$a3, bsy_tmain_spawn_stk($a3)
			lw	$a2, 0($fp)
			add	$a2, $a2, 1
			mul	$a2, $a2, 10
			addu	$a2, $a2, $t0
			la	$a1, bsy_t2main
			li	$t3, THR_STATE_SIZE
			mul	$a0, $t3, $t0
			la	$a0, bsy_tmain_thr_states($a0)
			sw	$t0, -4($fp)
			jal	thr_init
			lw	$t0, -4($fp)
			addu	$sp, $sp, 4
			addu	$t0, $t0, 1
bsy_tmain_spawn_test:	blt	$t0, 5, bsy_tmain_spawn
			li	$t0, 0
			b	bsy_tmain_test
			.data
bsy_tmain_msg0:		.asciiz	"Thread "
bsy_tmain_msg1:		.asciiz ": "
bsy_tmain_msg2:		.asciiz "\n"
			.text
bsy_tmain_bod:		la	$a0, bsy_tmain_msg0
			li	$v0, 4
			syscall
			lw	$a0, 0($fp)
			li	$v0, 1
			syscall
			la	$a0, bsy_tmain_msg1
			li	$v0, 4
			syscall
			move	$a0, $t0
			li	$v0, 1
			syscall
			la	$a0, bsy_tmain_msg2
			li	$v0, 4
			syscall
			sw	$t0, -4($fp)
			jal	thr_yield
			lw	$t0, -4($fp)
			addiu	$t0, $t0, 1
			sw	$t0, -4($fp)
bsy_tmain_test:		blt	$t0, 10, bsy_tmain_bod

			lw	$ra, -8($fp)
			lw	$fp, -12($fp)
			addu	$sp, $sp, 16
			jr	$ra

bsy_foo:		subu	$sp, $sp, 12
			sw	$fp, 4($sp)
			addu	$fp, $sp, 12
			sw	$ra, -4($fp)

			.data
bsy_foo_msg0:		.asciiz	"I am thread "
bsy_foo_msg1:		.asciiz	", and this is "
bsy_foo_msg2:		.asciiz	" times through\n"
			.text

			sw	$a0, 0($fp)
			la	$a0, bsy_foo_msg0
			li	$v0, 4
			syscall
			lw	$a0, 0($fp)
			li	$v0, 1
			syscall
			la	$a0, bsy_foo_msg1
			li	$v0, 4
			syscall
			move	$a0, $a1
			li	$v0, 1
			syscall
			la	$a0, bsy_foo_msg2
			li	$v0, 4
			syscall

			jal	thr_yield

			lw	$ra, -4($fp)
			lw	$fp, -8($fp)
			addu	$sp, $sp, 12
			jr	$ra

bsy_t2main:		subu	$sp, $sp, 16
			sw	$fp, 4($sp)
			addu	$fp, $sp, 16
			sw	$ra, -8($fp)

			sw	$a0, 0($fp)	# thread_id
			move	$t0, $zero	# i
			b	bsy_t2test
bsy_t2bod:			sw	$t0, -4($fp)
			move	$a1, $t0
			lw	$a0, 0($fp)
			jal	bsy_foo
			.data
bsy_t2_msg0:		.asciiz	"[ "
bsy_t2_msg1:		.asciiz ":"
bsy_t2_msg2:		.asciiz " ]\n"
			.text
			la	$a0, bsy_t2_msg0
			li	$v0, 4
			syscall
			lw	$a0, 0($fp)
			li	$v0, 1
			syscall
			la	$a0, bsy_t2_msg1
			li	$v0, 4
			syscall
			lw	$t0, -4($fp)
			move	$a0, $t0
			li	$v0, 1
			syscall
			la	$a0, bsy_t2_msg2
			li	$v0, 4
			syscall
			jal	thr_yield
			lw	$t0, -4($fp)
			addiu	$t0, $t0, 1
bsy_t2test:		blt	$t0, 10, bsy_t2bod

			lw	$ra, -8($fp)
			lw	$fp, -12($fp)
			addu	$sp, $sp, 16
			jr	$ra

			.globl main
#
#   8 + 3 * THR_STATE_SIZE + 3 * 4 * 512
# = 8 + 3 * 68 + 3 * 2048
# = 8 + 204 + 6144
# = 6356
#
# fp ->	t2stk	-2044($fp)
#	t1stk	-4092($fp)
#	t0stk	-6140($fp)
#	t2	-6440($fp) 300 byte states
#	t1	-6740($fp)
#	t0	-7040($fp)
#	old-ra	-7044($fp)
#	old-fp	-7048($fp)
# sp ->
main:			subu	$sp, $sp, 7052
			sw	$fp, 4($sp)
			sw	$ra, 8($sp)
			addu	$fp, $sp, 7052

			li	$t0, 2048
			subu	$sp, $sp, 4
			sw	$t0, 4($sp)	# push shared 4th arg

			la	$a3, -6140($fp)
			li	$a2, 0
			la	$a1, bsy_tmain
			la	$a0, -7040($fp)
			jal	thr_init

			la	$a3, -4092($fp)
			li	$a2, 1
			la	$a1, bsy_t2main
			la	$a0, -6740($fp)
			jal	thr_init

			la	$a3, -2044($fp)
			li	$a2, 2
			la	$a1, bsy_t2main
			la	$a0, -6440($fp)
			jal	thr_init

			addu	$sp, $sp, 4	# pop shared 4th arg

			li	$a1, 2
			la	$a0, -7040($fp)
			jal	thr_set_pri

			li	$a1, 2
			la	$a0, -6740($fp)
			jal	thr_set_pri

			li	$a1, 1
			la	$a0, -6440($fp)
			jal	thr_set_pri

			jal	thr_go

			.data
bsy_done_msg:		.asciiz "All done!\n"
			.text

			la	$a0, bsy_done_msg
			li	$v0, 4
			syscall

			lw	$ra, -7044($fp)
			lw	$fp, -7048($fp)
			addu	$sp, $sp, 7052
			jr	$ra